It's all about me

A friend pointed out to me lately that Vala can produce C code with clashing symbols. True, and I knew it was possible, but there is a solution. First however, the problem:

public class prefix {
    public static int other_name;
}
public class prefix_other {
    public static int name;
}
int main() {
    prefix.other_name = 1;
    prefix_other.name = 2;
    return 0;
}

And the solution:

public class prefix {
    [CCode(cname = "prefix_other_name2")]
    public static int other_name;
}
public class prefix_other {
    public static int name;
}
int main() {
    prefix.other_name = 1;
    prefix_other.name = 2;
    return 0;
}

Now that may seem like a hack, but that’s OK. Please remember that the stated goal of Vala is to bring the benefits of a modern programming language to GLib, whilst keeping compatibility (paraphrased). GLib is C based, with naming conventions, and coding standards that must be followed. So it follows that Vala must follow them, right down to the mechanisms for choosing variable names.

In Vala, many things operate as they would in the C world. Even structs appear to do so, with one exception. When passing a struct as a parameter, it is passed by reference. So, the signature some_method(ref MyStruct s) produces identical code to the signature some_method(MyStruct s). Try the following code sample:

struct MyStruct {
    public int a;
    public int b;
}
void other(MyStruct s) {
    s.a = 10;
}
int main() {
    MyStruct s = {2,3};
    other(s);
    stdout.printf("a=%d\n", s.a);
    return 0;
}

This outputs ’10′. Not what you might expect. Well, it turns out that there is a way to get back the good old behaviour, on a per struct basis. The SimpleType attribute:

[SimpleType]
struct MyStruct {
    public int a;
    public int b;
}
void other(MyStruct s) {
    s.a = 10;
}
int main() {
    MyStruct s = {2,3};
    other(s);
    stdout.printf("a=%d\n", s.a);
    return 0;
}

The output this time is ’2′. Yey!

Vala, DBus, interfaces and segfaults in the valac compiler. Take note, when you markup an interface with the DBus attribute, that interface must extend Object. If it extends nothing, valac will segfault mysteriously.

Try the following code sample:

[DBus(name = "com.my.interface")]
public interface MyIface {
    public abstract void hello();
}
static int main(string[] args) {
    return 0;
}

And compile with:

valac --pkg gio-2.0 test.vala

Notice the output:

** (valac:31817): CRITICAL **: vala_ccode_identifier_construct: assertion `_name != NULL' failed
** (valac:31817): CRITICAL **: vala_ccode_identifier_construct: assertion `_name != NULL' failed
Segmentation fault

Now modify the interface to extend Object as follows:

[DBus(name = "com.my.interface")]
public interface MyIface : Object {
    public abstract void hello();
}
static int main(string[] args) {
    return 0;
}